home *** CD-ROM | disk | FTP | other *** search
/ Scene Storm / Scene Storm - Volume 1.iso / coding / asm / demos / retinarave / include / menu-play.s < prev    next >
Text File  |  1980-01-03  |  23KB  |  1,168 lines
  1. ;********************************************
  2. ;* ----- Protracker V1.1B Playroutine ----- *
  3. ;* Lars "Zap" Hamre/Amiga Freelancers 1991  *
  4. ;* Bekkeliveien 10, N-2010 STRØMMEN, Norway *
  5. ;********************************************
  6.  
  7. ; VBlank Version 2:
  8. ; Call mt_init to initialize the routine, then call mt_music on
  9. ; each vertical blank (50 Hz). To end the song and turn off all
  10. ; voices, call mt_end.
  11.  
  12. ; This playroutine is not very fast, optimized or well commented,
  13. ; but all the new commands in PT1.1A should work.
  14. ; If it's not good enough, you'll have to change it yourself.
  15. ; We'll try to write a faster routine soon...
  16.  
  17. ; Changes from V1.0C playroutine:
  18. ; - Vibrato depth changed to be compatible with Noisetracker 2.0.
  19. ;   You'll have to double all vib. depths on old PT modules.
  20. ; - Funk Repeat changed to Invert Loop.
  21. ; - Period set back earlier when stopping an effect.
  22.  
  23. DMAWait = 300 ; Set this as low as possible without losing low notes.
  24.  
  25. n_note        EQU    0  ; W
  26. n_cmd        EQU    2  ; W
  27. n_cmdlo        EQU    3  ; B
  28. n_start        EQU    4  ; L
  29. n_length    EQU    8  ; W
  30. n_loopstart    EQU    10 ; L
  31. n_replen    EQU    14 ; W
  32. n_period    EQU    16 ; W
  33. n_finetune    EQU    18 ; B
  34. n_volume    EQU    19 ; B
  35. n_dmabit    EQU    20 ; W
  36. n_toneportdirec    EQU    22 ; B
  37. n_toneportspeed    EQU    23 ; B
  38. n_wantedperiod    EQU    24 ; W
  39. n_vibratocmd    EQU    26 ; B
  40. n_vibratopos    EQU    27 ; B
  41. n_tremolocmd    EQU    28 ; B
  42. n_tremolopos    EQU    29 ; B
  43. n_wavecontrol    EQU    30 ; B
  44. n_glissfunk    EQU    31 ; B
  45. n_sampleoffset    EQU    32 ; B
  46. n_pattpos    EQU    33 ; B
  47. n_loopcount    EQU    34 ; B
  48. n_funkoffset    EQU    35 ; B
  49. n_wavestart    EQU    36 ; L
  50. n_reallength    EQU    40 ; W
  51.  
  52. mt_init    move.l    MusicAdd,A0
  53.     MOVE.L    A0,mt_SongDataPtr
  54.     MOVE.L    A0,A1
  55.     LEA    952(A1),A1
  56.     MOVEQ    #127,D0
  57.     MOVEQ    #0,D1
  58. mtloop    MOVE.L    D1,D2
  59.     SUBQ.W    #1,D0
  60. mtloop2    MOVE.B    (A1)+,D1
  61.     CMP.B    D2,D1
  62.     BGT.S    mtloop
  63.     DBRA    D0,mtloop2
  64.     ADDQ.B    #1,D2
  65.             
  66.     LEA    mt_SampleStarts(PC),A1
  67.     ASL.L    #8,D2
  68.     ASL.L    #2,D2
  69.     ADD.L    #1084,D2
  70.     ADD.L    A0,D2
  71.     MOVE.L    D2,A2
  72.     MOVEQ    #30,D0
  73. mtloop3    CLR.L    (A2)
  74.     MOVE.L    A2,(A1)+
  75.     MOVEQ    #0,D1
  76.     MOVE.W    42(A0),D1
  77.     ASL.L    #1,D1
  78.     ADD.L    D1,A2
  79.     ADD.L    #30,A0
  80.     DBRA    D0,mtloop3
  81.  
  82.     OR.B    #2,$BFE001
  83.     MOVE.B    #6,mt_speed
  84.     CLR.B    mt_counter
  85.     CLR.B    mt_SongPos
  86.     CLR.W    mt_PatternPos
  87. mt_end    CLR.W    $DFF0A8
  88.     CLR.W    $DFF0B8
  89.     CLR.W    $DFF0C8
  90.     CLR.W    $DFF0D8
  91.     MOVE.W    #$F,$DFF096
  92.     RTS
  93.  
  94. mt_music
  95.     MOVEM.L    D0-D4/A0-A6,-(SP)
  96.     sub.w #$011,Equalizer1
  97.     bpl Eq1Ok
  98.     move.w #0,Equalizer1
  99. Eq1Ok:
  100.     sub.w #$010,Equalizer2
  101.     bpl Eq2Ok
  102.     move.w #0,Equalizer2
  103. Eq2Ok:
  104.     sub.w #$100,Equalizer3
  105.     bpl Eq3Ok
  106.     move.w #0,Equalizer3
  107. Eq3Ok:
  108.     sub.w #$101,Equalizer4
  109.     bpl Eq4Ok
  110.     move.w #0,Equalizer4
  111. Eq4Ok:
  112.  
  113.  
  114.  
  115.     ADDQ.B    #1,mt_counter
  116.     MOVE.B    mt_counter(PC),D0
  117.     CMP.B    mt_speed(PC),D0
  118.     BLO.S    mt_NoNewNote
  119.     CLR.B    mt_counter
  120.     TST.B    mt_PattDelTime2
  121.     BEQ.S    mt_GetNewNote
  122.     BSR.S    mt_NoNewAllChannels
  123.     BRA    mt_dskip
  124.  
  125. mt_NoNewNote
  126.     BSR.S    mt_NoNewAllChannels
  127.     BRA    mt_NoNewPosYet
  128.  
  129. mt_NoNewAllChannels
  130.     LEA    $DFF0A0,A5
  131.     LEA    mt_chan1temp(PC),A6
  132.     BSR    mt_CheckEfx
  133.     LEA    $DFF0B0,A5
  134.     LEA    mt_chan2temp(PC),A6
  135.     BSR    mt_CheckEfx
  136.     LEA    $DFF0C0,A5
  137.     LEA    mt_chan3temp(PC),A6
  138.     BSR    mt_CheckEfx
  139.     LEA    $DFF0D0,A5
  140.     LEA    mt_chan4temp(PC),A6
  141.     BRA    mt_CheckEfx
  142.  
  143. mt_GetNewNote
  144.     MOVE.L    mt_SongDataPtr(PC),A0
  145.     LEA    12(A0),A3
  146.     LEA    952(A0),A2    ;pattpo
  147.     LEA    1084(A0),A0    ;patterndata
  148.     MOVEQ    #0,D0
  149.     MOVEQ    #0,D1
  150.     MOVE.B    mt_SongPos(PC),D0
  151.     MOVE.B    (A2,D0.W),D1
  152.     ASL.L    #8,D1
  153.     ASL.L    #2,D1
  154.     ADD.W    mt_PatternPos(PC),D1
  155.     CLR.W    mt_DMACONtemp
  156.  
  157.     LEA    $DFF0A0,A5
  158.     LEA    mt_chan1temp(PC),A6
  159.     BSR.S    mt_PlayVoice
  160.     LEA    $DFF0B0,A5
  161.     LEA    mt_chan2temp(PC),A6
  162.     BSR.S    mt_PlayVoice
  163.     LEA    $DFF0C0,A5
  164.     LEA    mt_chan3temp(PC),A6
  165.     BSR.S    mt_PlayVoice
  166.     LEA    $DFF0D0,A5
  167.     LEA    mt_chan4temp(PC),A6
  168.     BSR.S    mt_PlayVoice
  169.     BRA    mt_SetDMA
  170.  
  171. mt_PlayVoice
  172.     TST.L    (A6)
  173.     BNE.S    mt_plvskip
  174.     BSR    mt_PerNop
  175. mt_plvskip
  176.     MOVE.L    (A0,D1.L),(A6)
  177.     ADDQ.L    #4,D1
  178.     MOVEQ    #0,D2
  179.     MOVE.B    n_cmd(A6),D2
  180.     AND.B    #$F0,D2
  181.     LSR.B    #4,D2
  182.     MOVE.B    (A6),D0
  183.     AND.B    #$F0,D0
  184.     OR.B    D0,D2
  185.     TST.B    D2
  186.     BEQ    mt_SetRegs
  187.     MOVEQ    #0,D3
  188.     LEA    mt_SampleStarts(PC),A1
  189.     MOVE    D2,D4
  190.     SUBQ.L    #1,D2
  191.     ASL.L    #2,D2
  192.  
  193.     cmp.l #$dff0a0,a5
  194.     bne NoEqu1
  195.     move.w #$0ff,Equalizer1
  196. NoEqu1:
  197.     cmp.l #$dff0b0,a5
  198.     bne NoEqu2
  199.     move.w #$f0,Equalizer2
  200. NoEqu2:
  201.     cmp.l #$dff0c0,a5
  202.     bne NoEqu3
  203.     move.w #$f00,Equalizer3
  204. NoEqu3:
  205.     cmp.l #$dff0d0,a5
  206.     bne NoEqu4
  207.     move.w #$f0f,Equalizer4
  208. NoEqu4:
  209.  
  210.  
  211.     MULU    #30,D4
  212.     MOVE.L    (A1,D2.L),n_start(A6)
  213.     MOVE.W    (A3,D4.L),n_length(A6)
  214.     MOVE.W    (A3,D4.L),n_reallength(A6)
  215.     MOVE.B    2(A3,D4.L),n_finetune(A6)
  216.     MOVE.B    3(A3,D4.L),n_volume(A6)
  217.     MOVE.W    4(A3,D4.L),D3 ; Get repeat
  218.     TST.W    D3
  219.     BEQ.S    mt_NoLoop
  220.     MOVE.L    n_start(A6),D2    ; Get start
  221.     ASL.W    #1,D3
  222.     ADD.L    D3,D2        ; Add repeat
  223.     MOVE.L    D2,n_loopstart(A6)
  224.     MOVE.L    D2,n_wavestart(A6)
  225.     MOVE.W    4(A3,D4.L),D0    ; Get repeat
  226.     ADD.W    6(A3,D4.L),D0    ; Add replen
  227.     MOVE.W    D0,n_length(A6)
  228.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  229.     MOVEQ    #0,D0
  230.     MOVE.B    n_volume(A6),D0
  231.     MOVE.W    D0,8(A5)    ; Set volume
  232.     BRA.S    mt_SetRegs
  233.  
  234. mt_NoLoop
  235.     MOVE.L    n_start(A6),D2
  236.     ADD.L    D3,D2
  237.     MOVE.L    D2,n_loopstart(A6)
  238.     MOVE.L    D2,n_wavestart(A6)
  239.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  240.     MOVEQ    #0,D0
  241.     MOVE.B    n_volume(A6),D0
  242.     MOVE.W    D0,8(A5)    ; Set volume
  243. mt_SetRegs
  244.     MOVE.W    (A6),D0
  245.     AND.W    #$0FFF,D0
  246.     BEQ    mt_CheckMoreEfx    ; If no note
  247.     MOVE.W    2(A6),D0
  248.     AND.W    #$0FF0,D0
  249.     CMP.W    #$0E50,D0
  250.     BEQ.S    mt_DoSetFineTune
  251.     MOVE.B    2(A6),D0
  252.     AND.B    #$0F,D0
  253.     CMP.B    #3,D0    ; TonePortamento
  254.     BEQ.S    mt_ChkTonePorta
  255.     CMP.B    #5,D0
  256.     BEQ.S    mt_ChkTonePorta
  257.     CMP.B    #9,D0    ; Sample Offset
  258.     BNE.S    mt_SetPeriod
  259.     BSR    mt_CheckMoreEfx
  260.     BRA.S    mt_SetPeriod
  261.  
  262. mt_DoSetFineTune
  263.     BSR    mt_SetFineTune
  264.     BRA.S    mt_SetPeriod
  265.  
  266. mt_ChkTonePorta
  267.     BSR    mt_SetTonePorta
  268.     BRA    mt_CheckMoreEfx
  269.  
  270. mt_SetPeriod
  271.     MOVEM.L    D0-D1/A0-A1,-(SP)
  272.     MOVE.W    (A6),D1
  273.     AND.W    #$0FFF,D1
  274.     LEA    mt_PeriodTable(PC),A1
  275.     MOVEQ    #0,D0
  276.     MOVEQ    #36,D7
  277. mt_ftuloop
  278.     CMP.W    (A1,D0.W),D1
  279.     BHS.S    mt_ftufound
  280.     ADDQ.L    #2,D0
  281.     DBRA    D7,mt_ftuloop
  282. mt_ftufound
  283.     MOVEQ    #0,D1
  284.     MOVE.B    n_finetune(A6),D1
  285.     MULU    #36*2,D1
  286.     ADD.L    D1,A1
  287.     MOVE.W    (A1,D0.W),n_period(A6)
  288.     MOVEM.L    (SP)+,D0-D1/A0-A1
  289.  
  290.     MOVE.W    2(A6),D0
  291.     AND.W    #$0FF0,D0
  292.     CMP.W    #$0ED0,D0 ; Notedelay
  293.     BEQ    mt_CheckMoreEfx
  294.  
  295.     MOVE.W    n_dmabit(A6),$DFF096
  296.     BTST    #2,n_wavecontrol(A6)
  297.     BNE.S    mt_vibnoc
  298.     CLR.B    n_vibratopos(A6)
  299. mt_vibnoc
  300.     BTST    #6,n_wavecontrol(A6)
  301.     BNE.S    mt_trenoc
  302.     CLR.B    n_tremolopos(A6)
  303. mt_trenoc
  304.     MOVE.L    n_start(A6),(A5)    ; Set start
  305.     MOVE.W    n_length(A6),4(A5)    ; Set length
  306.     MOVE.W    n_period(A6),D0
  307.     MOVE.W    D0,6(A5)        ; Set period
  308.     MOVE.W    n_dmabit(A6),D0
  309.     OR.W    D0,mt_DMACONtemp
  310.     BRA    mt_CheckMoreEfx
  311.  
  312. mt_SetDMA
  313.     MOVE.W    #300,D0
  314. mt_WaitDMA
  315.     DBRA    D0,mt_WaitDMA
  316.     MOVE.W    mt_DMACONtemp(PC),D0
  317.     OR.W    #$8000,D0
  318.     MOVE.W    D0,$DFF096
  319.     MOVE.W    #300,D0
  320. mt_WaitDMA2
  321.     DBRA    D0,mt_WaitDMA2
  322.  
  323.     LEA    $DFF000,A5
  324.     LEA    mt_chan4temp(PC),A6
  325.     MOVE.L    n_loopstart(A6),$D0(A5)
  326.     MOVE.W    n_replen(A6),$D4(A5)
  327.     LEA    mt_chan3temp(PC),A6
  328.     MOVE.L    n_loopstart(A6),$C0(A5)
  329.     MOVE.W    n_replen(A6),$C4(A5)
  330.     LEA    mt_chan2temp(PC),A6
  331.     MOVE.L    n_loopstart(A6),$B0(A5)
  332.     MOVE.W    n_replen(A6),$B4(A5)
  333.     LEA    mt_chan1temp(PC),A6
  334.     MOVE.L    n_loopstart(A6),$A0(A5)
  335.     MOVE.W    n_replen(A6),$A4(A5)
  336.  
  337. mt_dskip
  338.     ADD.W    #16,mt_PatternPos
  339.     MOVE.B    mt_PattDelTime,D0
  340.     BEQ.S    mt_dskc
  341.     MOVE.B    D0,mt_PattDelTime2
  342.     CLR.B    mt_PattDelTime
  343. mt_dskc    TST.B    mt_PattDelTime2
  344.     BEQ.S    mt_dska
  345.     SUBQ.B    #1,mt_PattDelTime2
  346.     BEQ.S    mt_dska
  347.     SUB.W    #16,mt_PatternPos
  348. mt_dska    TST.B    mt_PBreakFlag
  349.     BEQ.S    mt_nnpysk
  350.     SF    mt_PBreakFlag
  351.     MOVEQ    #0,D0
  352.     MOVE.B    mt_PBreakPos(PC),D0
  353.     CLR.B    mt_PBreakPos
  354.     LSL.W    #4,D0
  355.     MOVE.W    D0,mt_PatternPos
  356. mt_nnpysk
  357.     CMP.W    #1024,mt_PatternPos
  358.     BLO.S    mt_NoNewPosYet
  359. mt_NextPosition    
  360.     MOVEQ    #0,D0
  361.     MOVE.B    mt_PBreakPos(PC),D0
  362.     LSL.W    #4,D0
  363.     MOVE.W    D0,mt_PatternPos
  364.     CLR.B    mt_PBreakPos
  365.     CLR.B    mt_PosJumpFlag
  366.     ADDQ.B    #1,mt_SongPos
  367.     AND.B    #$7F,mt_SongPos
  368.     MOVE.B    mt_SongPos(PC),D1
  369.     MOVE.L    mt_SongDataPtr(PC),A0
  370.     CMP.B    950(A0),D1
  371.     BLO.S    mt_NoNewPosYet
  372.     CLR.B    mt_SongPos
  373. mt_NoNewPosYet    
  374.     TST.B    mt_PosJumpFlag
  375.     BNE.S    mt_NextPosition
  376.     MOVEM.L    (SP)+,D0-D4/A0-A6
  377.     RTS
  378.  
  379. mt_CheckEfx
  380.     BSR    mt_UpdateFunk
  381.     MOVE.W    n_cmd(A6),D0
  382.     AND.W    #$0FFF,D0
  383.     BEQ.S    mt_PerNop
  384.     MOVE.B    n_cmd(A6),D0
  385.     AND.B    #$0F,D0
  386.     BEQ.S    mt_Arpeggio
  387.     CMP.B    #1,D0
  388.     BEQ    mt_PortaUp
  389.     CMP.B    #2,D0
  390.     BEQ    mt_PortaDown
  391.     CMP.B    #3,D0
  392.     BEQ    mt_TonePortamento
  393.     CMP.B    #4,D0
  394.     BEQ    mt_Vibrato
  395.     CMP.B    #5,D0
  396.     BEQ    mt_TonePlusVolSlide
  397.     CMP.B    #6,D0
  398.     BEQ    mt_VibratoPlusVolSlide
  399.     CMP.B    #$E,D0
  400.     BEQ    mt_E_Commands
  401. SetBack    MOVE.W    n_period(A6),6(A5)
  402.     CMP.B    #7,D0
  403.     BEQ    mt_Tremolo
  404.     CMP.B    #$A,D0
  405.     BEQ    mt_VolumeSlide
  406. mt_Return2
  407.     RTS
  408.  
  409. mt_PerNop
  410.     MOVE.W    n_period(A6),6(A5)
  411.     RTS
  412.  
  413. mt_Arpeggio
  414.     MOVEQ    #0,D0
  415.     MOVE.B    mt_counter(PC),D0
  416.     DIVS    #3,D0
  417.     SWAP    D0
  418.     CMP.W    #0,D0
  419.     BEQ.S    mt_Arpeggio2
  420.     CMP.W    #2,D0
  421.     BEQ.S    mt_Arpeggio1
  422.     MOVEQ    #0,D0
  423.     MOVE.B    n_cmdlo(A6),D0
  424.     LSR.B    #4,D0
  425.     BRA.S    mt_Arpeggio3
  426.  
  427. mt_Arpeggio1
  428.     MOVEQ    #0,D0
  429.     MOVE.B    n_cmdlo(A6),D0
  430.     AND.B    #15,D0
  431.     BRA.S    mt_Arpeggio3
  432.  
  433. mt_Arpeggio2
  434.     MOVE.W    n_period(A6),D2
  435.     BRA.S    mt_Arpeggio4
  436.  
  437. mt_Arpeggio3
  438.     ASL.W    #1,D0
  439.     MOVEQ    #0,D1
  440.     MOVE.B    n_finetune(A6),D1
  441.     MULU    #36*2,D1
  442.     LEA    mt_PeriodTable(PC),A0
  443.     ADD.L    D1,A0
  444.     MOVEQ    #0,D1
  445.     MOVE.W    n_period(A6),D1
  446.     MOVEQ    #36,D7
  447. mt_arploop
  448.     MOVE.W    (A0,D0.W),D2
  449.     CMP.W    (A0),D1
  450.     BHS.S    mt_Arpeggio4
  451.     ADDQ.L    #2,A0
  452.     DBRA    D7,mt_arploop
  453.     RTS
  454.  
  455. mt_Arpeggio4
  456.     MOVE.W    D2,6(A5)
  457.     RTS
  458.  
  459. mt_FinePortaUp
  460.     TST.B    mt_counter
  461.     BNE.S    mt_Return2
  462.     MOVE.B    #$0F,mt_LowMask
  463. mt_PortaUp
  464.     MOVEQ    #0,D0
  465.     MOVE.B    n_cmdlo(A6),D0
  466.     AND.B    mt_LowMask(PC),D0
  467.     MOVE.B    #$FF,mt_LowMask
  468.     SUB.W    D0,n_period(A6)
  469.     MOVE.W    n_period(A6),D0
  470.     AND.W    #$0FFF,D0
  471.     CMP.W    #113,D0
  472.     BPL.S    mt_PortaUskip
  473.     AND.W    #$F000,n_period(A6)
  474.     OR.W    #113,n_period(A6)
  475. mt_PortaUskip
  476.     MOVE.W    n_period(A6),D0
  477.     AND.W    #$0FFF,D0
  478.     MOVE.W    D0,6(A5)
  479.     RTS    
  480.  
  481. mt_FinePortaDown
  482.     TST.B    mt_counter
  483.     BNE    mt_Return2
  484.     MOVE.B    #$0F,mt_LowMask
  485. mt_PortaDown
  486.     CLR.W    D0
  487.     MOVE.B    n_cmdlo(A6),D0
  488.     AND.B    mt_LowMask(PC),D0
  489.     MOVE.B    #$FF,mt_LowMask
  490.     ADD.W    D0,n_period(A6)
  491.     MOVE.W    n_period(A6),D0
  492.     AND.W    #$0FFF,D0
  493.     CMP.W    #856,D0
  494.     BMI.S    mt_PortaDskip
  495.     AND.W    #$F000,n_period(A6)
  496.     OR.W    #856,n_period(A6)
  497. mt_PortaDskip
  498.     MOVE.W    n_period(A6),D0
  499.     AND.W    #$0FFF,D0
  500.     MOVE.W    D0,6(A5)
  501.     RTS
  502.  
  503. mt_SetTonePorta
  504.     MOVE.L    A0,-(SP)
  505.     MOVE.W    (A6),D2
  506.     AND.W    #$0FFF,D2
  507.     MOVEQ    #0,D0
  508.     MOVE.B    n_finetune(A6),D0
  509.     MULU    #37*2,D0
  510.     LEA    mt_PeriodTable(PC),A0
  511.     ADD.L    D0,A0
  512.     MOVEQ    #0,D0
  513. mt_StpLoop
  514.     CMP.W    (A0,D0.W),D2
  515.     BHS.S    mt_StpFound
  516.     ADDQ.W    #2,D0
  517.     CMP.W    #37*2,D0
  518.     BLO.S    mt_StpLoop
  519.     MOVEQ    #35*2,D0
  520. mt_StpFound
  521.     MOVE.B    n_finetune(A6),D2
  522.     AND.B    #8,D2
  523.     BEQ.S    mt_StpGoss
  524.     TST.W    D0
  525.     BEQ.S    mt_StpGoss
  526.     SUBQ.W    #2,D0
  527. mt_StpGoss
  528.     MOVE.W    (A0,D0.W),D2
  529.     MOVE.L    (SP)+,A0
  530.     MOVE.W    D2,n_wantedperiod(A6)
  531.     MOVE.W    n_period(A6),D0
  532.     CLR.B    n_toneportdirec(A6)
  533.     CMP.W    D0,D2
  534.     BEQ.S    mt_ClearTonePorta
  535.     BGE    mt_Return2
  536.     MOVE.B    #1,n_toneportdirec(A6)
  537.     RTS
  538.  
  539. mt_ClearTonePorta
  540.     CLR.W    n_wantedperiod(A6)
  541.     RTS
  542.  
  543. mt_TonePortamento
  544.     MOVE.B    n_cmdlo(A6),D0
  545.     BEQ.S    mt_TonePortNoChange
  546.     MOVE.B    D0,n_toneportspeed(A6)
  547.     CLR.B    n_cmdlo(A6)
  548. mt_TonePortNoChange
  549.     TST.W    n_wantedperiod(A6)
  550.     BEQ    mt_Return2
  551.     MOVEQ    #0,D0
  552.     MOVE.B    n_toneportspeed(A6),D0
  553.     TST.B    n_toneportdirec(A6)
  554.     BNE.S    mt_TonePortaUp
  555. mt_TonePortaDown
  556.     ADD.W    D0,n_period(A6)
  557.     MOVE.W    n_wantedperiod(A6),D0
  558.     CMP.W    n_period(A6),D0
  559.     BGT.S    mt_TonePortaSetPer
  560.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  561.     CLR.W    n_wantedperiod(A6)
  562.     BRA.S    mt_TonePortaSetPer
  563.  
  564. mt_TonePortaUp
  565.     SUB.W    D0,n_period(A6)
  566.     MOVE.W    n_wantedperiod(A6),D0
  567.     CMP.W    n_period(A6),D0
  568.     BLT.S    mt_TonePortaSetPer
  569.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  570.     CLR.W    n_wantedperiod(A6)
  571.  
  572. mt_TonePortaSetPer
  573.     MOVE.W    n_period(A6),D2
  574.     MOVE.B    n_glissfunk(A6),D0
  575.     AND.B    #$0F,D0
  576.     BEQ.S    mt_GlissSkip
  577.     MOVEQ    #0,D0
  578.     MOVE.B    n_finetune(A6),D0
  579.     MULU    #36*2,D0
  580.     LEA    mt_PeriodTable(PC),A0
  581.     ADD.L    D0,A0
  582.     MOVEQ    #0,D0
  583. mt_GlissLoop
  584.     CMP.W    (A0,D0.W),D2
  585.     BHS.S    mt_GlissFound
  586.     ADDQ.W    #2,D0
  587.     CMP.W    #36*2,D0
  588.     BLO.S    mt_GlissLoop
  589.     MOVEQ    #35*2,D0
  590. mt_GlissFound
  591.     MOVE.W    (A0,D0.W),D2
  592. mt_GlissSkip
  593.     MOVE.W    D2,6(A5) ; Set period
  594.     RTS
  595.  
  596. mt_Vibrato
  597.     MOVE.B    n_cmdlo(A6),D0
  598.     BEQ.S    mt_Vibrato2
  599.     MOVE.B    n_vibratocmd(A6),D2
  600.     AND.B    #$0F,D0
  601.     BEQ.S    mt_vibskip
  602.     AND.B    #$F0,D2
  603.     OR.B    D0,D2
  604. mt_vibskip
  605.     MOVE.B    n_cmdlo(A6),D0
  606.     AND.B    #$F0,D0
  607.     BEQ.S    mt_vibskip2
  608.     AND.B    #$0F,D2
  609.     OR.B    D0,D2
  610. mt_vibskip2
  611.     MOVE.B    D2,n_vibratocmd(A6)
  612. mt_Vibrato2
  613.     MOVE.B    n_vibratopos(A6),D0
  614.     LEA    mt_VibratoTable(PC),A4
  615.     LSR.W    #2,D0
  616.     AND.W    #$001F,D0
  617.     MOVEQ    #0,D2
  618.     MOVE.B    n_wavecontrol(A6),D2
  619.     AND.B    #$03,D2
  620.     BEQ.S    mt_vib_sine
  621.     LSL.B    #3,D0
  622.     CMP.B    #1,D2
  623.     BEQ.S    mt_vib_rampdown
  624.     MOVE.B    #255,D2
  625.     BRA.S    mt_vib_set
  626. mt_vib_rampdown
  627.     TST.B    n_vibratopos(A6)
  628.     BPL.S    mt_vib_rampdown2
  629.     MOVE.B    #255,D2
  630.     SUB.B    D0,D2
  631.     BRA.S    mt_vib_set
  632. mt_vib_rampdown2
  633.     MOVE.B    D0,D2
  634.     BRA.S    mt_vib_set
  635. mt_vib_sine
  636.     MOVE.B    0(A4,D0.W),D2
  637. mt_vib_set
  638.     MOVE.B    n_vibratocmd(A6),D0
  639.     AND.W    #15,D0
  640.     MULU    D0,D2
  641.     LSR.W    #7,D2
  642.     MOVE.W    n_period(A6),D0
  643.     TST.B    n_vibratopos(A6)
  644.     BMI.S    mt_VibratoNeg
  645.     ADD.W    D2,D0
  646.     BRA.S    mt_Vibrato3
  647. mt_VibratoNeg
  648.     SUB.W    D2,D0
  649. mt_Vibrato3
  650.     MOVE.W    D0,6(A5)
  651.     MOVE.B    n_vibratocmd(A6),D0
  652.     LSR.W    #2,D0
  653.     AND.W    #$003C,D0
  654.     ADD.B    D0,n_vibratopos(A6)
  655.     RTS
  656.  
  657. mt_TonePlusVolSlide
  658.     BSR    mt_TonePortNoChange
  659.     BRA    mt_VolumeSlide
  660.  
  661. mt_VibratoPlusVolSlide
  662.     BSR.S    mt_Vibrato2
  663.     BRA    mt_VolumeSlide
  664.  
  665. mt_Tremolo
  666.     MOVE.B    n_cmdlo(A6),D0
  667.     BEQ.S    mt_Tremolo2
  668.     MOVE.B    n_tremolocmd(A6),D2
  669.     AND.B    #$0F,D0
  670.     BEQ.S    mt_treskip
  671.     AND.B    #$F0,D2
  672.     OR.B    D0,D2
  673. mt_treskip
  674.     MOVE.B    n_cmdlo(A6),D0
  675.     AND.B    #$F0,D0
  676.     BEQ.S    mt_treskip2
  677.     AND.B    #$0F,D2
  678.     OR.B    D0,D2
  679. mt_treskip2
  680.     MOVE.B    D2,n_tremolocmd(A6)
  681. mt_Tremolo2
  682.     MOVE.B    n_tremolopos(A6),D0
  683.     LEA    mt_VibratoTable(PC),A4
  684.     LSR.W    #2,D0
  685.     AND.W    #$001F,D0
  686.     MOVEQ    #0,D2
  687.     MOVE.B    n_wavecontrol(A6),D2
  688.     LSR.B    #4,D2
  689.     AND.B    #$03,D2
  690.     BEQ.S    mt_tre_sine
  691.     LSL.B    #3,D0
  692.     CMP.B    #1,D2
  693.     BEQ.S    mt_tre_rampdown
  694.     MOVE.B    #255,D2
  695.     BRA.S    mt_tre_set
  696. mt_tre_rampdown
  697.     TST.B    n_vibratopos(A6)
  698.     BPL.S    mt_tre_rampdown2
  699.     MOVE.B    #255,D2
  700.     SUB.B    D0,D2
  701.     BRA.S    mt_tre_set
  702. mt_tre_rampdown2
  703.     MOVE.B    D0,D2
  704.     BRA.S    mt_tre_set
  705. mt_tre_sine
  706.     MOVE.B    0(A4,D0.W),D2
  707. mt_tre_set
  708.     MOVE.B    n_tremolocmd(A6),D0
  709.     AND.W    #15,D0
  710.     MULU    D0,D2
  711.     LSR.W    #6,D2
  712.     MOVEQ    #0,D0
  713.     MOVE.B    n_volume(A6),D0
  714.     TST.B    n_tremolopos(A6)
  715.     BMI.S    mt_TremoloNeg
  716.     ADD.W    D2,D0
  717.     BRA.S    mt_Tremolo3
  718. mt_TremoloNeg
  719.     SUB.W    D2,D0
  720. mt_Tremolo3
  721.     BPL.S    mt_TremoloSkip
  722.     CLR.W    D0
  723. mt_TremoloSkip
  724.     CMP.W    #$40,D0
  725.     BLS.S    mt_TremoloOk
  726.     MOVE.W    #$40,D0
  727. mt_TremoloOk
  728.     MOVE.W    D0,8(A5)
  729.     MOVE.B    n_tremolocmd(A6),D0
  730.     LSR.W    #2,D0
  731.     AND.W    #$003C,D0
  732.     ADD.B    D0,n_tremolopos(A6)
  733.     RTS
  734.  
  735. mt_SampleOffset
  736.     MOVEQ    #0,D0
  737.     MOVE.B    n_cmdlo(A6),D0
  738.     BEQ.S    mt_sononew
  739.     MOVE.B    D0,n_sampleoffset(A6)
  740. mt_sononew
  741.     MOVE.B    n_sampleoffset(A6),D0
  742.     LSL.W    #7,D0
  743.     CMP.W    n_length(A6),D0
  744.     BGE.S    mt_sofskip
  745.     SUB.W    D0,n_length(A6)
  746.     LSL.W    #1,D0
  747.     ADD.L    D0,n_start(A6)
  748.     RTS
  749. mt_sofskip
  750.     MOVE.W    #$0001,n_length(A6)
  751.     RTS
  752.  
  753. mt_VolumeSlide
  754.     MOVEQ    #0,D0
  755.     MOVE.B    n_cmdlo(A6),D0
  756.     LSR.B    #4,D0
  757.     TST.B    D0
  758.     BEQ.S    mt_VolSlideDown
  759. mt_VolSlideUp
  760.     ADD.B    D0,n_volume(A6)
  761.     CMP.B    #$40,n_volume(A6)
  762.     BMI.S    mt_vsuskip
  763.     MOVE.B    #$40,n_volume(A6)
  764. mt_vsuskip
  765.     MOVE.B    n_volume(A6),D0
  766.     MOVE.W    D0,8(A5)
  767.     RTS
  768.  
  769. mt_VolSlideDown
  770.     MOVEQ    #0,D0
  771.     MOVE.B    n_cmdlo(A6),D0
  772.     AND.B    #$0F,D0
  773. mt_VolSlideDown2
  774.     SUB.B    D0,n_volume(A6)
  775.     BPL.S    mt_vsdskip
  776.     CLR.B    n_volume(A6)
  777. mt_vsdskip
  778.     MOVE.B    n_volume(A6),D0
  779.     MOVE.W    D0,8(A5)
  780.     RTS
  781.  
  782. mt_PositionJump
  783.     MOVE.B    n_cmdlo(A6),D0
  784.     SUBQ.B    #1,D0
  785.     MOVE.B    D0,mt_SongPos
  786. mt_pj2    CLR.B    mt_PBreakPos
  787.     ST     mt_PosJumpFlag
  788.     RTS
  789.  
  790. mt_VolumeChange
  791.     MOVEQ    #0,D0
  792.     MOVE.B    n_cmdlo(A6),D0
  793.     CMP.B    #$40,D0
  794.     BLS.S    mt_VolumeOk
  795.     MOVEQ    #$40,D0
  796. mt_VolumeOk
  797.     MOVE.B    D0,n_volume(A6)
  798.     MOVE.W    D0,8(A5)
  799.     RTS
  800.  
  801. mt_PatternBreak
  802.     MOVEQ    #0,D0
  803.     MOVE.B    n_cmdlo(A6),D0
  804.     MOVE.L    D0,D2
  805.     LSR.B    #4,D0
  806.     MULU    #10,D0
  807.     AND.B    #$0F,D2
  808.     ADD.B    D2,D0
  809.     CMP.B    #63,D0
  810.     BHI.S    mt_pj2
  811.     MOVE.B    D0,mt_PBreakPos
  812.     ST    mt_PosJumpFlag
  813.     RTS
  814.  
  815. mt_SetSpeed
  816.     MOVE.B    3(A6),D0
  817.     BEQ    mt_Return2
  818.     CLR.B    mt_counter
  819.     MOVE.B    D0,mt_speed
  820.     RTS
  821.  
  822. mt_CheckMoreEfx
  823.     BSR    mt_UpdateFunk
  824.     MOVE.B    2(A6),D0
  825.     AND.B    #$0F,D0
  826.     CMP.B    #$9,D0
  827.     BEQ    mt_SampleOffset
  828.     CMP.B    #$B,D0
  829.     BEQ    mt_PositionJump
  830.     CMP.B    #$D,D0
  831.     BEQ.S    mt_PatternBreak
  832.     CMP.B    #$E,D0
  833.     BEQ.S    mt_E_Commands
  834.     CMP.B    #$F,D0
  835.     BEQ.S    mt_SetSpeed
  836.     CMP.B    #$C,D0
  837.     BEQ    mt_VolumeChange
  838.     BRA    mt_PerNop
  839.  
  840. mt_E_Commands
  841.     MOVE.B    n_cmdlo(A6),D0
  842.     AND.B    #$F0,D0
  843.     LSR.B    #4,D0
  844.     BEQ.S    mt_FilterOnOff
  845.     CMP.B    #1,D0
  846.     BEQ    mt_FinePortaUp
  847.     CMP.B    #2,D0
  848.     BEQ    mt_FinePortaDown
  849.     CMP.B    #3,D0
  850.     BEQ.S    mt_SetGlissControl
  851.     CMP.B    #4,D0
  852.     BEQ    mt_SetVibratoControl
  853.     CMP.B    #5,D0
  854.     BEQ    mt_SetFineTune
  855.     CMP.B    #6,D0
  856.     BEQ    mt_JumpLoop
  857.     CMP.B    #7,D0
  858.     BEQ    mt_SetTremoloControl
  859.     CMP.B    #9,D0
  860.     BEQ    mt_RetrigNote
  861.     CMP.B    #$A,D0
  862.     BEQ    mt_VolumeFineUp
  863.     CMP.B    #$B,D0
  864.     BEQ    mt_VolumeFineDown
  865.     CMP.B    #$C,D0
  866.     BEQ    mt_NoteCut
  867.     CMP.B    #$D,D0
  868.     BEQ    mt_NoteDelay
  869.     CMP.B    #$E,D0
  870.     BEQ    mt_PatternDelay
  871.     CMP.B    #$F,D0
  872.     BEQ    mt_FunkIt
  873.     RTS
  874.  
  875. mt_FilterOnOff
  876.     MOVE.B    n_cmdlo(A6),D0
  877.     AND.B    #1,D0
  878.     ASL.B    #1,D0
  879.     AND.B    #$FD,$BFE001
  880.     OR.B    D0,$BFE001
  881.     RTS    
  882.  
  883. mt_SetGlissControl
  884.     MOVE.B    n_cmdlo(A6),D0
  885.     AND.B    #$0F,D0
  886.     AND.B    #$F0,n_glissfunk(A6)
  887.     OR.B    D0,n_glissfunk(A6)
  888.     RTS
  889.  
  890. mt_SetVibratoControl
  891.     MOVE.B    n_cmdlo(A6),D0
  892.     AND.B    #$0F,D0
  893.     AND.B    #$F0,n_wavecontrol(A6)
  894.     OR.B    D0,n_wavecontrol(A6)
  895.     RTS
  896.  
  897. mt_SetFineTune
  898.     MOVE.B    n_cmdlo(A6),D0
  899.     AND.B    #$0F,D0
  900.     MOVE.B    D0,n_finetune(A6)
  901.     RTS
  902.  
  903. mt_JumpLoop
  904.     TST.B    mt_counter
  905.     BNE    mt_Return2
  906.     MOVE.B    n_cmdlo(A6),D0
  907.     AND.B    #$0F,D0
  908.     BEQ.S    mt_SetLoop
  909.     TST.B    n_loopcount(A6)
  910.     BEQ.S    mt_jumpcnt
  911.     SUBQ.B    #1,n_loopcount(A6)
  912.     BEQ    mt_Return2
  913. mt_jmploop    MOVE.B    n_pattpos(A6),mt_PBreakPos
  914.     ST    mt_PBreakFlag
  915.     RTS
  916.  
  917. mt_jumpcnt
  918.     MOVE.B    D0,n_loopcount(A6)
  919.     BRA.S    mt_jmploop
  920.  
  921. mt_SetLoop
  922.     MOVE.W    mt_PatternPos(PC),D0
  923.     LSR.W    #4,D0
  924.     MOVE.B    D0,n_pattpos(A6)
  925.     RTS
  926.  
  927. mt_SetTremoloControl
  928.     MOVE.B    n_cmdlo(A6),D0
  929.     AND.B    #$0F,D0
  930.     LSL.B    #4,D0
  931.     AND.B    #$0F,n_wavecontrol(A6)
  932.     OR.B    D0,n_wavecontrol(A6)
  933.     RTS
  934.  
  935. mt_RetrigNote
  936.     MOVE.L    D1,-(SP)
  937.     MOVEQ    #0,D0
  938.     MOVE.B    n_cmdlo(A6),D0
  939.     AND.B    #$0F,D0
  940.     BEQ.S    mt_rtnend
  941.     MOVEQ    #0,D1
  942.     MOVE.B    mt_counter(PC),D1
  943.     BNE.S    mt_rtnskp
  944.     MOVE.W    (A6),D1
  945.     AND.W    #$0FFF,D1
  946.     BNE.S    mt_rtnend
  947.     MOVEQ    #0,D1
  948.     MOVE.B    mt_counter(PC),D1
  949. mt_rtnskp
  950.     DIVU    D0,D1
  951.     SWAP    D1
  952.     TST.W    D1
  953.     BNE.S    mt_rtnend
  954. mt_DoRetrig
  955.     MOVE.W    n_dmabit(A6),$DFF096    ; Channel DMA off
  956.     MOVE.L    n_start(A6),(A5)    ; Set sampledata pointer
  957.     MOVE.W    n_length(A6),4(A5)    ; Set length
  958.     MOVE.W    #300,D0
  959. mt_rtnloop1
  960.     DBRA    D0,mt_rtnloop1
  961.     MOVE.W    n_dmabit(A6),D0
  962.     BSET    #15,D0
  963.     MOVE.W    D0,$DFF096
  964.     MOVE.W    #300,D0
  965. mt_rtnloop2
  966.     DBRA    D0,mt_rtnloop2
  967.     MOVE.L    n_loopstart(A6),(A5)
  968.     MOVE.L    n_replen(A6),4(A5)
  969. mt_rtnend
  970.     MOVE.L    (SP)+,D1
  971.     RTS
  972.  
  973. mt_VolumeFineUp
  974.     TST.B    mt_counter
  975.     BNE    mt_Return2
  976.     MOVEQ    #0,D0
  977.     MOVE.B    n_cmdlo(A6),D0
  978.     AND.B    #$F,D0
  979.     BRA    mt_VolSlideUp
  980.  
  981. mt_VolumeFineDown
  982.     TST.B    mt_counter
  983.     BNE    mt_Return2
  984.     MOVEQ    #0,D0
  985.     MOVE.B    n_cmdlo(A6),D0
  986.     AND.B    #$0F,D0
  987.     BRA    mt_VolSlideDown2
  988.  
  989. mt_NoteCut
  990.     MOVEQ    #0,D0
  991.     MOVE.B    n_cmdlo(A6),D0
  992.     AND.B    #$0F,D0
  993.     CMP.B    mt_counter(PC),D0
  994.     BNE    mt_Return2
  995.     CLR.B    n_volume(A6)
  996.     MOVE.W    #0,8(A5)
  997.     RTS
  998.  
  999. mt_NoteDelay
  1000.     MOVEQ    #0,D0
  1001.     MOVE.B    n_cmdlo(A6),D0
  1002.     AND.B    #$0F,D0
  1003.     CMP.B    mt_Counter,D0
  1004.     BNE    mt_Return2
  1005.     MOVE.W    (A6),D0
  1006.     BEQ    mt_Return2
  1007.     MOVE.L    D1,-(SP)
  1008.     BRA    mt_DoRetrig
  1009.  
  1010. mt_PatternDelay
  1011.     TST.B    mt_counter
  1012.     BNE    mt_Return2
  1013.     MOVEQ    #0,D0
  1014.     MOVE.B    n_cmdlo(A6),D0
  1015.     AND.B    #$0F,D0
  1016.     TST.B    mt_PattDelTime2
  1017.     BNE    mt_Return2
  1018.     ADDQ.B    #1,D0
  1019.     MOVE.B    D0,mt_PattDelTime
  1020.     RTS
  1021.  
  1022. mt_FunkIt
  1023.     TST.B    mt_counter
  1024.     BNE    mt_Return2
  1025.     MOVE.B    n_cmdlo(A6),D0
  1026.     AND.B    #$0F,D0
  1027.     LSL.B    #4,D0
  1028.     AND.B    #$0F,n_glissfunk(A6)
  1029.     OR.B    D0,n_glissfunk(A6)
  1030.     TST.B    D0
  1031.     BEQ    mt_Return2
  1032. mt_UpdateFunk
  1033.     MOVEM.L    A0/D1,-(SP)
  1034.     MOVEQ    #0,D0
  1035.     MOVE.B    n_glissfunk(A6),D0
  1036.     LSR.B    #4,D0
  1037.     BEQ.S    mt_funkend
  1038.     LEA    mt_FunkTable(PC),A0
  1039.     MOVE.B    (A0,D0.W),D0
  1040.     ADD.B    D0,n_funkoffset(A6)
  1041.     BTST    #7,n_funkoffset(A6)
  1042.     BEQ.S    mt_funkend
  1043.     CLR.B    n_funkoffset(A6)
  1044.  
  1045.     MOVE.L    n_loopstart(A6),D0
  1046.     MOVEQ    #0,D1
  1047.     MOVE.W    n_replen(A6),D1
  1048.     ADD.L    D1,D0
  1049.     ADD.L    D1,D0
  1050.     MOVE.L    n_wavestart(A6),A0
  1051.     ADDQ.L    #1,A0
  1052.     CMP.L    D0,A0
  1053.     BLO.S    mt_funkok
  1054.     MOVE.L    n_loopstart(A6),A0
  1055. mt_funkok
  1056.     MOVE.L    A0,n_wavestart(A6)
  1057.     MOVEQ    #-1,D0
  1058.     SUB.B    (A0),D0
  1059.     MOVE.B    D0,(A0)
  1060. mt_funkend
  1061.     MOVEM.L    (SP)+,A0/D1
  1062.     RTS
  1063.  
  1064.  
  1065. mt_FunkTable dc.b 0,5,6,7,8,10,11,13,16,19,22,26,32,43,64,128
  1066.  
  1067. mt_VibratoTable    
  1068.     dc.b   0, 24, 49, 74, 97,120,141,161
  1069.     dc.b 180,197,212,224,235,244,250,253
  1070.     dc.b 255,253,250,244,235,224,212,197
  1071.     dc.b 180,161,141,120, 97, 74, 49, 24
  1072.  
  1073. mt_PeriodTable
  1074. ; Tuning 0, Normal
  1075.     dc.w    856,808,762,720,678,640,604,570,538,508,480,453
  1076.     dc.w    428,404,381,360,339,320,302,285,269,254,240,226
  1077.     dc.w    214,202,190,180,170,160,151,143,135,127,120,113
  1078. ; Tuning 1
  1079.     dc.w    850,802,757,715,674,637,601,567,535,505,477,450
  1080.     dc.w    425,401,379,357,337,318,300,284,268,253,239,225
  1081.     dc.w    213,201,189,179,169,159,150,142,134,126,119,113
  1082. ; Tuning 2
  1083.     dc.w    844,796,752,709,670,632,597,563,532,502,474,447
  1084.     dc.w    422,398,376,355,335,316,298,282,266,251,237,224
  1085.     dc.w    211,199,188,177,167,158,149,141,133,125,118,112
  1086. ; Tuning 3
  1087.     dc.w    838,791,746,704,665,628,592,559,528,498,470,444
  1088.     dc.w    419,395,373,352,332,314,296,280,264,249,235,222
  1089.     dc.w    209,198,187,176,166,157,148,140,132,125,118,111
  1090. ; Tuning 4
  1091.     dc.w    832,785,741,699,660,623,588,555,524,495,467,441
  1092.     dc.w    416,392,370,350,330,312,294,278,262,247,233,220
  1093.     dc.w    208,196,185,175,165,156,147,139,131,124,117,110
  1094. ; Tuning 5
  1095.     dc.w    826,779,736,694,655,619,584,551,520,491,463,437
  1096.     dc.w    413,390,368,347,328,309,292,276,260,245,232,219
  1097.     dc.w    206,195,184,174,164,155,146,138,130,123,116,109
  1098. ; Tuning 6
  1099.     dc.w    820,774,730,689,651,614,580,547,516,487,460,434
  1100.     dc.w    410,387,365,345,325,307,290,274,258,244,230,217
  1101.     dc.w    205,193,183,172,163,154,145,137,129,122,115,109
  1102. ; Tuning 7
  1103.     dc.w    814,768,725,684,646,610,575,543,513,484,457,431
  1104.     dc.w    407,384,363,342,323,305,288,272,256,242,228,216
  1105.     dc.w    204,192,181,171,161,152,144,136,128,121,114,108
  1106. ; Tuning -8
  1107.     dc.w    907,856,808,762,720,678,640,604,570,538,508,480
  1108.     dc.w    453,428,404,381,360,339,320,302,285,269,254,240
  1109.     dc.w    226,214,202,190,180,170,160,151,143,135,127,120
  1110. ; Tuning -7
  1111.     dc.w    900,850,802,757,715,675,636,601,567,535,505,477
  1112.     dc.w    450,425,401,379,357,337,318,300,284,268,253,238
  1113.     dc.w    225,212,200,189,179,169,159,150,142,134,126,119
  1114. ; Tuning -6
  1115.     dc.w    894,844,796,752,709,670,632,597,563,532,502,474
  1116.     dc.w    447,422,398,376,355,335,316,298,282,266,251,237
  1117.     dc.w    223,211,199,188,177,167,158,149,141,133,125,118
  1118. ; Tuning -5
  1119.     dc.w    887,838,791,746,704,665,628,592,559,528,498,470
  1120.     dc.w    444,419,395,373,352,332,314,296,280,264,249,235
  1121.     dc.w    222,209,198,187,176,166,157,148,140,132,125,118
  1122. ; Tuning -4
  1123.     dc.w    881,832,785,741,699,660,623,588,555,524,494,467
  1124.     dc.w    441,416,392,370,350,330,312,294,278,262,247,233
  1125.     dc.w    220,208,196,185,175,165,156,147,139,131,123,117
  1126. ; Tuning -3
  1127.     dc.w    875,826,779,736,694,655,619,584,551,520,491,463
  1128.     dc.w    437,413,390,368,347,328,309,292,276,260,245,232
  1129.     dc.w    219,206,195,184,174,164,155,146,138,130,123,116
  1130. ; Tuning -2
  1131.     dc.w    868,820,774,730,689,651,614,580,547,516,487,460
  1132.     dc.w    434,410,387,365,345,325,307,290,274,258,244,230
  1133.     dc.w    217,205,193,183,172,163,154,145,137,129,122,115
  1134. ; Tuning -1
  1135.     dc.w    862,814,768,725,684,646,610,575,543,513,484,457
  1136.     dc.w    431,407,384,363,342,323,305,288,272,256,242,228
  1137.     dc.w    216,203,192,181,171,161,152,144,136,128,121,114
  1138.  
  1139. mt_chan1temp    dc.l    0,0,0,0,0,$00010000,0,  0,0,0,0
  1140. mt_chan2temp    dc.l    0,0,0,0,0,$00020000,0,  0,0,0,0
  1141. mt_chan3temp    dc.l    0,0,0,0,0,$00040000,0,  0,0,0,0
  1142. mt_chan4temp    dc.l    0,0,0,0,0,$00080000,0,  0,0,0,0
  1143.  
  1144. mt_SampleStarts    dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1145.         dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1146.  
  1147. mt_SongDataPtr    dc.l 0
  1148.  
  1149. mt_speed    dc.b 6
  1150. mt_counter    dc.b 0
  1151. mt_SongPos    dc.b 0
  1152. mt_PBreakPos    dc.b 0
  1153. mt_PosJumpFlag    dc.b 0
  1154. mt_PBreakFlag    dc.b 0
  1155. mt_LowMask    dc.b 0
  1156. mt_PattDelTime    dc.b 0
  1157. mt_PattDelTime2    dc.b 0,0
  1158.  
  1159. mt_PatternPos    dc.w 0
  1160. mt_DMACONtemp    dc.w 0
  1161.  
  1162. Equalizer1:    dc.w 0
  1163. Equalizer2:    dc.w 0
  1164. Equalizer3:    dc.w 0
  1165. Equalizer4:    dc.w 0
  1166.  
  1167. ;/* End of File */
  1168.